Style

Function calls

Most forms in Clojure programs are function calls. The parameters of function calls can be indented in two ways.

If you have multiple parameters, and they are too long or too many to put on the same line, you can align them:

(and (flush? hand)
     (straight? hand))

(defn grandmother? [person grandmother]
  (or (= grandmother (mother (mother person)))
      (= grandmother (mother (father person)))))

In some cases, you want to put the first parameter on its own line:

(and
  (flush? hand)
  (straight? hand))

In this case, the parameters are aligned and indented with either one or two spaces. Vim indents the parameters with two spaces and Emacs with one. Either style is fine.

Literal maps, vectors, sets and lists

The elements of a literal vector are aligned:

["foo" "bar"
 42 :quux
 (+ 1 2)]

Note that the elements on successive lines are not aligned to the opening [, but to the first element.

Maps, sets and lists are written in similarly:

{:foo 42
 :bar "quux"}
 
'("foo" "bar"
  42 :quux)

In a map the key and value are usually on the same line, but if they need to be on separate lines, they are aligned:

{:foo
 42
 :bar
 "quux"}

Definitions

The body of a definition is indented with two spaces:

(defn double [x]
  (+ x x))

If the parameters of a function definition are on separate lines, they are aligned, like literal vectors:

(defn foo [a-really-long-parameter-name
           another-long-parameter-name]
  (body))

If a definition has a documentation string, it is written on the next line after the definition name, indented with two spaces:

(defn foo
  "This is the documentation string for foo.
  It can span multiple lines."
  [parameters]
  (body))

In this case, the parameter vector is written on its own line and indented with two spaces, like the body.

let is indented very much like a function definition. The defined names are indented and aligned like a vector literal and the body is indented with two spaces:

(let [name "Lila Black"            ; ← name definitions here
      occupation "Magical Cyborg"] ; ← and here
  (str "I am " name ". "                   ; ← body here, indented two
       "Prepare to be " occupation "ed.")) ;   spaces more than the let

Here the aim is to make it visually clear where the name definitions are and where the body is, so the body is not aligned with the definitions.

As a somewhat special case, if is indented like definitions:

(if (= 3 4)
  "maths is broked"
  "all is fine")

The conditional is usually on the same line as the if, and the clause bodies are indented with two spaces.